Proyectos de Subversion LeadersLinked - Android

plugins {
    id 'com.android.application'
    id 'com.google.gms.google-services'
}

android {
    compileSdk 36

    defaultConfig {
        targetSdk 36
        applicationId "com.cesams.leaderslinked.v2"
        minSdkVersion 21
        versionCode 25
        versionName '1.1.16'

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    // Configuración de Product Flavors para diferentes entornos
    flavorDimensions "version"
    productFlavors {
        demo {
            dimension "version"
            applicationId "com.leaderslinked.demo"
            versionNameSuffix "-demo"
            resValue "string", "app_name", "LeadersLinked Demo"
            buildConfigField "String", "BASE_URL", "\"https://demo.leaderslinked.com\""
        }
        
        staging {
            dimension "version"
            applicationId "com.cesams.leaderslinked.v2.staging" 
            versionNameSuffix "-staging"
            resValue "string", "app_name", "LeadersLinked Staging"
            buildConfigField "String", "BASE_URL", "\"https://stanging.leaderslinked.com\""
        }

        v2 {
            dimension "version"
            applicationId "com.cesams.leaderslinked.v2"
            versionNameSuffix "-v2"
            resValue "string", "app_name", "LeadersLinked V2"
            buildConfigField "String", "BASE_URL", "\"https://v2.leaderslinked.com\""
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    buildFeatures {
        buildConfig true
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    namespace 'com.cesams.leaderslinked.v2'

}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation 'androidx.appcompat:appcompat:1.6.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
    // Add the Firebase SDK for Google Analytics
    implementation 'com.google.firebase:firebase-analytics:21.3.0'

    // Add the SDK for Firebase Cloud Messaging
    implementation 'com.google.firebase:firebase-messaging:23.2.1'

    implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'

    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test.ext:junit:1.1.5'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'
}